Main Page

Introduzione a LibMovIt su Wikibase

Benvenutə!

LibMovIt Wikibase è un progetto dedicato ai dati strutturati relativi al progetto PRIN 2022 LibMovIt LIBMOVIT - Libraries on the Move: Scholars, Books, Ideas Traveling in Italy in the 18th Century, progetto finanziato dall’Unione europea – Next Generation EU. Questa istanza di wikibase è stata creata per ospitare e pubblicare i dati prodotti nel corso della ricerca e per offrirne uno strumento avanzato di elaborazione e analisi. Questa istanza è ospitata su wikibase.cloud.

• Dai un'occhiata a un item di esempio
• Dai un'occhiata a un item a caso
• Crea un nuovo item
• Scrivi all'admin

---

Obiettivi del progetto LibMovIt su Wikibase

L'obiettivo principale del dataset di LibMovIt è registrare e mettere a disposizione i dati relativi alle informazioni fornite dai viaggiatori nei loro testi sulle biblioteche italiane visitate. A partire dai brani rilevanti dei testi, vengono registrati i dati di interesse relativi a:

• la biblioteca;
• le collezioni generali e speciali di una biblioteca;
• i servizi (apertura, orari, pubblico ecc.) di una biblioteca;
• gli oggetti più notevoli segnalati per una biblioteca (la presenza di opere di un autore, o di una particolare opera di un autore o di una particolare edizione ecc.);
• le persone e le organizzazioni segnalate o rilevanti in relazione a una biblioteca (proprietari, possessori, collezionisti, bibliotecari ecc.).

Le citazioni

Il punto di partenza per la raccolta e la registrazione dei dati sono i brani dei testi, ovvero le citazioni; Ecco due esempi:

(Martyn 1791, 24)

Of the royal library [di Torino], wherein are about 50,000 volumes of printed books, besides manuscripts; this is open every day, except holidays, both morning and afternoon.

(Albrizzi 1740, 41)

"Ora per questa medesima Scala si monta nella pubblica LIBRERIA, il cui Atrio è ridotto in forma di Museo ricco di molte Statue, Busti, Teste, Bassi-rilievi, Are ed Iscrizioni Greche e Latine, lasciate alla Repubblica per la maggior parte da Domenico Grimani Cardinale di S. Chiesa, altre da Giovanni Grimani Patriarca d'Aquileja, ed altre da Federigo Proccuratore di S. Marco. Quivi si conservano Libri singolari e in gran copia: ed una tale raccolta ebbe principio dopo la morte del Cardinale Bessarione, che fu prima Arcivescovo di Nicea, indi Patriarca di Costantinopoli. Questi avendo raccolti con grandissima diligenza fatica e spesa, una gran quantità di Codici Greci in qualsivoglia Scienza, e considerando che niun altro luogo era più sicuro e comodo della Città di Vinegia per depositarli a pubblica utilità, ne fece un liberalissimo dono al Senato, e ciò principalmente in riconoscimento del grande onore che aveva ricevuto dalla Repubblica, da cui era stato aggregato tra i suoi Nobili. Di tutto questo ne fa testimonianza la Iscrizione posta sopra la Porta della stessa Libreria, a memoria eterna di quel dotto Uomo, sopra Colonne di Serpentino e Mischio. Chi desiderasse di sapere il numero e la qualità de' Codici, legga l'Indice che ne ha pubblicato il Tomasini, e quello ultimamente stampato a spese Pubbliche di due volumi in fol. contenenti Codici sì Greci, come Latini. Tra questi sono degni di considerazione i Libri di S. Agostino de Trinitate, scritti in Greco ed in Latino; le Orazioni di Temistio, e la Biblioteca di Fozio; tutte e due queste Opere in Greco. Delle Opere scritte in Latino è stimabile molto la Comentazione di S. Agostino sopra le Pistole di S. Paolo. Furono poi fatti da altri ragguardevoli Uomini Letterati varj lasciti di Libri; come in questi ultimi tempi ne furono lasciati dal N. Giambattista Recanati: e dalla cura degli Eccellentissimi Signori Proccuratori, deputati alla soprintendenza della Libreria, viene questa giornalmente accresciuta. Oltre alla copia e alla preziosità de' Libri, potrà quivi ammirare ancora il Forestiere le celebri Pitture di Paolo Calliari, del Salviati, del Varotari, di Battista Franco, ec., circondate di grotetteschi, fogliami ed altri ornamenti [ecc.]"

---

Alcuni elementi di esempio

Martyn 1791, 24 (1) (Q30)

Albrizzi 1740, 41 (Q76)

---

Informazioni generali sul dataset

• Tutti gli elementi creati
• Tutte le proprietà create
• Tutti gli utenti
• Statistiche su questa istanza di Wikibase

Utenti coinvolti

• Carlo Bianchini (contribs)
• Lillegul (contribs)
• Epìdosis (contribs)
• Camilla Acampora (contribs)
• Martinacaroli (contribs)
• Barbara Allegranti (contribs)
• Domenico Ciccarello (contribs)
• Carlottacosentino (contribs)
• Anna Maria Marconi (contribs)
• CateM (contribs)
• Salo1996 (contribs)
• Arianna Pastorini (contribs)
• Manuparr (contribs)
• Viviana (contribs)
• Chiara Festa (contribs)
• Luca0321 (contribs)
• Glenda Furini (contribs)
• Riccardo Pallotto (contribs)
• GemmaScali (contribs)
• Jcapaldo (contribs)
• Elisabetta (contribs)
• Scuccurullo (contribs)
• Luciasardo (contribs)

---

Query

Categorie

Tipologie di biblioteca

# Tutte le sottoclassi di biblioteca

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P3* ld:Q5 .
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Tipologie di libro

# Tutte le sottoclassi di libri

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P3* ld:Q58 . # sottoclassi di Libro [Q58]
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Ruoli

# Tutte le sottoclassi di ruolo di un'entità rispetto a un'altra entità

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P3* ld:Q83 . # sottoclassi [P3*] di ruolo [Q83]
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

ORDER BY ?itemLabel

Provalo!

Utenti

# Tutte le sottoclassi di utenti delle biblioteche

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P3* ld:Q123 . # sottoclassi [P3*] di ruolo [Q123]
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

ORDER BY ?itemLabel

Provalo!

Nazionalità e genere di tutti gli autori

#Tutti gli autori suddivisi per paese di cittadinanza e genere

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?persona ?personaLabel  ?paese ?paeseLabel ?genere ?genereLabel  WHERE {
  
  ?persona ldt:P51 ?paese     .   # P51 paese di cittadinanza
  ?persona ldt:P45 ?genere . # P45 genere

 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
  
ORDER BY ?paeseLabel

Provalo!

Tutte le organizzazioni

#Tutte le sottoclassi di qualsiasi tipo di organizzazione

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT DISTINCT ?item ?itemLabel  WHERE {
  
  ?item ldt:P3* ld:Q11 . # P3* sottoclasse di Q11 organizzazione
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Istanze

Tutte le singole biblioteche di tipo conventuale

# Tutte le istanze di biblioteca conventuale

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P1 ld:Q74 . # P1 istanza di e Q74 biblioteca conventuale
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Tutte le singole biblioteche di tipo monastico

# Tutte le istanze di biblioteca monastica

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P1 ld:Q406 . # P1 istanza di e Q74 biblioteca conventuale
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Tutte le biblioteche ad accesso pubblico

# Tutte le biblioteche ad accesso pubblico

# Tutte le biblioteche ad accesso pubblico

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?luogoLabel WHERE {
  
  ?item ldt:P1 ld:Q75 . # P1 istanza di e Q75 * biblioteca ad accesso pubblico
  ?item ldt:P20 ?luogo
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Tutte le singole biblioteche di qualunque tipo

# Tutte le istanze di qualsiasi tipo di biblioteca 

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT DISTINCT ?item ?itemLabel WHERE {
  
  ?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza di o P3* sottoclasse di Q5 biblioteca
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Tutte le istanze di qualsiasi tipo di biblioteca e opere notevoli contenute

# Tutte le istanze di qualsiasi tipo di biblioteca e opere notevoli contenute

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT DISTINCT ?item ?itemLabel ?operaLabel WHERE {
  
  ?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza di o P3* sottoclasse di Q5 biblioteca
  ?item ldt:P18 ?opera    .  # P18 contiene 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Tutte le singole edizioni

# Tutte le istanze di edizioni in ordine di data di pubblicazione

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?itemDescription ?autore ?autoreLabel ?data WHERE {
  
  ?item ldt:P1 ld:Q9 . # P1 istanza di e Q9 edizione
  ?item ldt:P11 ?autore .
  ?item ldt:P40 ?data
        
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?data

Provalo!

Tutte le singole persone

# Tutte le persone con il loro eventuale ID Wikidata

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?ID_WD WHERE {
  
  ?item ldt:P1 ld:Q1 .
  OPTIONAL { ?item ldt:P78 ?ID_WD } .
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Tutte le singole collezioni

# Tutte le singole collezioni

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P1 ld:Q10 . # P1 istanza di Q10 collezione
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Citazioni

Tutte le citazioni tratte da Martyn

# Tutte le citazioni tratte da tutte le edizioni dell'opera di Martyn 1787

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q27 . #P8 tratto dall'opera Q27 opera di Martyn
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
        
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)

Provalo!

Tutte le citazioni tratte da Albrizzi

# Tutte le citazioni tratte da tutte le edizioni dell'opera di Albrizzi 1740

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?bibliotecaLabel WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q72 . #P8 tratto dall'opera Q72 di Albrizzi
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)

Provalo!

Tutte le citazioni tratte da La Marre

# Tutte le citazioni tratte da tutte le edizioni dell'opera di La Marre 1776

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q201 . #P8 tratto dall'opera Q201 opera di La Marre
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
        
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)

Provalo!

Tutte le citazioni tratte da Richard

# Tutte le citazioni tratte da tutte le edizioni dell'opera di Richard 1766

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q203 . #P8 tratto dall'opera Q203 opera di Richard
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
        
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)

Provalo!

Tutte le citazioni tratte da La Lande

# Tutte le citazioni tratte da La Lande

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q1210 . #P8 tratto dall'opera Q201 opera di La Lande
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
        
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)

Provalo!

Tutte le citazioni inserite, per autore e pagina

# Tutte le citazioni inserite ordinate per autore e per pagina

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ?opera .
  ?opera ldt:P11 ?autore .
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
        
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by ?autore xsd:integer(?pagina)

Provalo!

Tutte le citazioni inserite ordinate per data e per pagina della Biblioteca dell'Istituto di Scienze di Bologna

# Tutte le citazioni inserite ordinate per data e per pagina della Biblioteca dell'Istituto di Scienze di Bologna

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?data WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ?opera .
  ?opera ldt:P16 ?data .
  ?opera ldt:P11 ?autore .
  ?item ldt:P13 ld:Q371 . # P13 ha come soggetto la ?biblioteca
 
        
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by ?data

Provalo!

Tutte le citazioni inserite ordinate per data e per pagina della Biblioteca Marciana a Venezia

# Tutte le citazioni inserite ordinate per data e per pagina della Biblioteca Marciana a Venezia

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?data WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ?opera .
  ?opera ldt:P16 ?data .
  ?opera ldt:P11 ?autore .
  ?item ldt:P13 ld:Q78 . # P13 ha come soggetto la ?biblioteca
 
        
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by ?data

Provalo!

Grafici

Grafico a bolle del numero di biblioteche in base al tipo

#Grafico che mostra la quantità delle biblioteche in base alla tipologia
#defaultView:BubbleChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?biblioteca ?bibliotecaLabel (COUNT(?biblioteca) as ?count) WHERE {
  
    ?item ldt:P1/ldt:P3* ld:Q5 .
   ?item ldt:P1 ?biblioteca .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,it,en". }

} 
GROUP BY ?biblioteca ?bibliotecaLabel ?count

Provalo!

Grafico a bolle delle biblioteche citate più frequentemente, con almeno 5 citazioni

#Biblioteche citate più frequentemente grafico a bolle, con almeno 5 citazioni; 
#defaultView:BubbleChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT DISTINCT ?biblioLabel (COUNT(?item) AS ?totale) #mostra le biblioteche e conta il totale di item, cioè citazioni
WHERE {
  ?item ldt:P1 ld:Q3. #definisce ?item come una citazione (Q3)
  ?item ldt:P13 ?biblio . # definisce la biblioteca come soggetto della citazione
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?biblioLabel  # raggruppa per biblioteca
HAVING (?totale > 4)
ORDER BY DESC(?totale) # ordina in numero decrescente

Provalo!

Grafo ad albero delle sottoclassi di biblioteca

#title:Tutte le sottoclassi di biblioteca
#defaultView:Graph
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?linkTo WHERE {
  
  ?item ldt:P3* ld:Q5 .
  OPTIONAL { ?linkTo ldt:P3 ?item . FILTER(?linkTo != ld:Q5) } .
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Tutte le sottoclassi di biblioteca

Istogramma del numero di biblioteche in base al tipo

#title: Numero di biblioteche per tipologia
#defaultView:BarChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?biblioteca ?bibliotecaLabel (COUNT(?biblioteca) as ?count) WHERE {
  
    ?item ldt:P1/ldt:P3* ld:Q5 .
   ?item ldt:P1 ?biblioteca .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,it,en". }

} 
GROUP BY ?biblioteca ?bibliotecaLabel ?count

Numero di biblioteche per tipologia

Istogramma del numero di biblioteche citate più frequentemente, con almeno 5 citazioni

#Biblioteche citate più frequentemente grafico a barre, con almeno 5 citazioni; 
#defaultView:BarChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?biblioLabel (COUNT(?item) AS ?totale) #mostra le biblioteche e conta il totale di item, cioè citazioni
WHERE {
  ?item ldt:P1 ld:Q3. #definisce ?item come una citazione (Q3)
  ?item ldt:P13 ?biblio . # definisce la biblioteca come soggetto della citazione
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?biblioLabel  # raggruppa per biblioteca
HAVING (?totale > 4)
ORDER BY DESC(?totale) # ordina in numero decrescente

Provalo!

Istogramma del numero di persone in base all'occupazione

#title: Numero di persone per occupazione
#defaultView:BarChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?occupazione ?occupazioneLabel (COUNT(?occupazione) as ?numero) WHERE {
  
    ?item ldt:P1 ld:Q1 .
   ?item ldt:P70 ?occupazione .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,it,en". }

} 
GROUP BY ?occupazione ?occupazioneLabel ?numero

Numero di persone per occupazione

Query federata LibMovIt e Wikidata

Mappa di tutte le città in cui ci sono biblioteche citate nelle opere dei viaggiatori

# Mappa di tutte le città in cui ci sono biblioteche citate nelle opere dei viaggiatori (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate
#defaultView:Map
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord WHERE {  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
  ?luogo ldt:P78 ?wdlink .
  BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
    SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord . }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Citazioni in relazione alla città sede delle biblioteche menzionate

Mappa di tutte le città in cui ci sono biblioteche citate nell'opera di Martyn

# Mappa di tutte le città in cui ci sono biblioteche citate da Martyn 1787 (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate da Martyn 1787
#defaultView:Map
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord WHERE {  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q27 . #P8 tratto dall'opera Q27 opera di Martyn
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
  ?luogo ldt:P78 ?wdlink .
  BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
    SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord . }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Citazioni in relazione alla città sede delle biblioteche menzionate da Martyn 1787

Mappa di tutte le città in cui ci sono biblioteche citate nell'opera di La Marre (volume 1)

# Mappa di tutte le città in cui ci sono biblioteche citate da La Marre (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate da La Marre nel primo volume
#defaultView:Map
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT DISTINCT  ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord WHERE {  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q201  . #P8 tratto dall'opera Q27 opera di La Marre
   ?item ldt:P82 "1" . 
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
  ?luogo ldt:P78 ?wdlink .
  BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
    SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord . }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Citazioni in relazione alla città sede delle biblioteche menzionate da La Marre nel primo volume

Mappa di tutte le città in cui ci sono biblioteche citate nell'opera di La Marre (volume 2)

# Mappa di tutte le città in cui ci sono biblioteche citate da La Marre (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate da La Marre nel secondo volume
#defaultView:Map
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT DISTINCT  ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord WHERE {  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q201  . #P8 tratto dall'opera Q27 opera di La Marre
   ?item ldt:P82 "2" . 
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
  ?luogo ldt:P78 ?wdlink .
  BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
    SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord . }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Citazioni in relazione alla città sede delle biblioteche menzionate da La Marre nel secondo volume

Occupazione e paese di cittadinanza delle persone estratti da Wikidata

# Dati relativi all'occupazione e al paese di cittadinanza degli autori delle fonti di LibMovIt (occupazione e paese sono estratti da Wikidata)
#title:Occupazione e paese di cittadinanza degli autori delle fonti estratti da Wikidata
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT DISTINCT ?item ?itemLabel ?ID_WD ?occupazione ?paese WHERE {
  
  ?item ldt:P1 ld:Q1 .
  ?opera ldt:P11 ?item . #la persona è autore di un'opera
  ?citaz ldt:P8 ?opera . # l'opera è un'opera che ha almeno una citazione
  ?item ldt:P78 ?ID_WD .
  BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?ID_WD))) AS ?wditem)
  OPTIONAL { SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P106 ?occupazione } .}
  OPTIONAL { SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P27 ?paese } .}
 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by ?itemLabel

Occupazione e paese di cittadinanza degli autori delle fonti estratti da Wikidata

Citazioni in relazione alla città sede delle biblioteche menzionate

# Mappa di tutte le città in cui ci sono biblioteche citate nelle opere dei viaggiatori (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate
#defaultView:Map
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord ?layer WHERE {
  ?item ldt:P4 ?brano;
    ldt:P13 ?biblioteca.
  ?biblioteca ldt:P20 ?luogo.
  ?luogo ldt:P78 ?wdlink.
  ?item ldt:P8 ?opera.
  ?opera ldt:P11 ?autore.
  ?autore rdfs:label ?autori.
  FILTER((LANG(?autori)) = "en")
  BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
  BIND(?autori AS ?layer)
  SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE,en]". }
}

Citazioni in relazione alla città sede delle biblioteche menzionate