Main Page
Introduzione a Wikibase LibMovIt Project
Benvenutə!
Wikibase LibMovIt è un progetto a cura dell'unità di ricerca dell'Università di Pavia dedicato ai dati strutturati relativi al PRIN 2022 LibMovIt LIBMOVIT - Libraries on the Move: Scholars, Books, Ideas Traveling in Italy in the 18th Century, progetto finanziato dall’Unione europea – Next Generation EU, coordinato dall'Università di Bologna e in collaborazione con il CNR-ILIESI. Questa istanza di wikibase è stata creata per ospitare e pubblicare i dati prodotti nel corso della ricerca e per offrirne uno strumento avanzato di elaborazione e analisi. Questa istanza è ospitata su wikibase.cloud.
- Dai un'occhiata a un item di esempio
- Dai un'occhiata a un item a caso
- Crea un nuovo item
- Scrivi all'admin
Obiettivi del progetto Wikibase LibMovIt
L'obiettivo principale del dataset Wikibase LibMovIt è registrare e mettere a disposizione i dati relativi alle informazioni fornite dai viaggiatori nei loro testi sulle biblioteche italiane visitate. A partire dai brani rilevanti dei testi, vengono registrati i dati di interesse relativi a:
- la biblioteca;
- le collezioni generali e speciali di una biblioteca;
- i servizi (apertura, orari, pubblico ecc.) di una biblioteca;
- gli oggetti più notevoli segnalati per una biblioteca (la presenza di opere di un autore, o di una particolare opera di un autore o di una particolare edizione ecc.);
- le persone e le organizzazioni segnalate o rilevanti in relazione a una biblioteca (proprietari, possessori, collezionisti, bibliotecari ecc.).
Le citazioni
Il punto di partenza per la raccolta e la registrazione dei dati sono i brani dei testi, ovvero le citazioni; Ecco due esempi:
(Martyn 1791, 24)
Of the royal library [di Torino], wherein are about 50,000 volumes of printed books, besides manuscripts; this is open every day, except holidays, both morning and afternoon.
(Albrizzi 1740, 41)
"Ora per questa medesima Scala si monta nella pubblica LIBRERIA, il cui Atrio è ridotto in forma di Museo ricco di molte Statue, Busti, Teste, Bassi-rilievi, Are ed Iscrizioni Greche e Latine, lasciate alla Repubblica per la maggior parte da Domenico Grimani Cardinale di S. Chiesa, altre da Giovanni Grimani Patriarca d'Aquileja, ed altre da Federigo Proccuratore di S. Marco. Quivi si conservano Libri singolari e in gran copia: ed una tale raccolta ebbe principio dopo la morte del Cardinale Bessarione, che fu prima Arcivescovo di Nicea, indi Patriarca di Costantinopoli. Questi avendo raccolti con grandissima diligenza fatica e spesa, una gran quantità di Codici Greci in qualsivoglia Scienza, e considerando che niun altro luogo era più sicuro e comodo della Città di Vinegia per depositarli a pubblica utilità, ne fece un liberalissimo dono al Senato, e ciò principalmente in riconoscimento del grande onore che aveva ricevuto dalla Repubblica, da cui era stato aggregato tra i suoi Nobili. Di tutto questo ne fa testimonianza la Iscrizione posta sopra la Porta della stessa Libreria, a memoria eterna di quel dotto Uomo, sopra Colonne di Serpentino e Mischio. Chi desiderasse di sapere il numero e la qualità de' Codici, legga l'Indice che ne ha pubblicato il Tomasini, e quello ultimamente stampato a spese Pubbliche di due volumi in fol. contenenti Codici sì Greci, come Latini. Tra questi sono degni di considerazione i Libri di S. Agostino de Trinitate, scritti in Greco ed in Latino; le Orazioni di Temistio, e la Biblioteca di Fozio; tutte e due queste Opere in Greco. Delle Opere scritte in Latino è stimabile molto la Comentazione di S. Agostino sopra le Pistole di S. Paolo. Furono poi fatti da altri ragguardevoli Uomini Letterati varj lasciti di Libri; come in questi ultimi tempi ne furono lasciati dal N. Giambattista Recanati: e dalla cura degli Eccellentissimi Signori Proccuratori, deputati alla soprintendenza della Libreria, viene questa giornalmente accresciuta. Oltre alla copia e alla preziosità de' Libri, potrà quivi ammirare ancora il Forestiere le celebri Pitture di Paolo Calliari, del Salviati, del Varotari, di Battista Franco, ec., circondate di grotetteschi, fogliami ed altri ornamenti [ecc.]"
Alcuni elementi di esempio
Informazioni generali sul dataset
- Tutti gli elementi creati
- Tutte le proprietà create
- Tutti gli utenti
- Statistiche su questa istanza di Wikibase
Utenti coinvolti
- Carlo Bianchini (contribs)
- Lillegul (contribs)
- Epìdosis (contribs)
- Camilla Acampora (contribs)
- Martinacaroli (contribs)
- Barbara Allegranti (contribs)
- Domenico Ciccarello (contribs)
- Carlottacosentino (contribs)
- Anna Maria Marconi (contribs)
- CateM (contribs)
- Salo1996 (contribs)
- Arianna Pastorini (contribs)
- Manuparr (contribs)
- Viviana (contribs)
- Chiara Festa (contribs)
- Luca0321 (contribs)
- Glenda Furini (contribs)
- Riccardo Pallotto (contribs)
- GemmaScali (contribs)
- Jcapaldo (contribs)
- Elisabetta (contribs)
- Scuccurullo (contribs)
- Luciasardo (contribs)
Query
Classi
Elenco delle classi definite in LibMovIt con il numero delle relative istanze
# Tutte le classi con il numero delle relative istanze
PREFIX lmiwdt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
SELECT ?istanzaLabel (COUNT(?q) AS ?count) WHERE {
?q lmiwdt:P1 ?istanza.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?istanza ?istanzaLabel
ORDER BY DESC(?count)
Classi di biblioteca
# Tutte le classi e sottoclassi di biblioteca
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel WHERE {
?item ldt:P3* ld:Q5 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Classi di libro
# Tutte le classi e sottoclassi di libri
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel WHERE {
?item ldt:P3* ld:Q58 . # sottoclassi di Libro [Q58]
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze
Istanze della classe Ruolo
# Tutte le istanze di ruolo, proprietà che collega due entità tra loro
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel WHERE {
?item ldt:P1 ld:Q83 . # sottoclassi [P3*] di ruolo [Q83]
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze della classe Utenti
# Istanze della classe Utenti
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel WHERE {
?item ldt:P3* ld:Q123 . # sottoclassi [P3*] di ruolo [Q123]
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze della classe Organizzazioni
#Tutte le classi e sottoclassi di qualsiasi tipo di organizzazione
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel WHERE {
?item ldt:P1/ldt:P3* ld:Q11 . # P1 istanze o P3* sottoclassi di Q11 organizzazione
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze della classe Edifici
# #Tutte le istanze e sottoclassi di qualsiasi tipo di edificio
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?luogoLabel WHERE {
?item ldt:P1/ldt:P3* ld:Q1995 . # P1 istanza/P3* sottoclasse di Q1995
?item ldt:P73 ?luogo . # luogo geografico
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze della classe Edizioni
Istanze della classe Edizione in ordine di data di pubblicazione
# Tutte le istanze di edizioni in ordine di data di pubblicazione
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?itemDescription ?autore ?autoreLabel ?data WHERE {
?item ldt:P1 ld:Q9 . # P1 istanza di e Q9 edizione
?item ldt:P11 ?autore .
?item ldt:P40 ?data
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?data
Istanze della classe Edizione in ordine di lingua
# Tutte le istanze di edizioni ordinate per lingua
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?itemDescription ?autore ?autoreLabel ?linguaLabel WHERE {
?item ldt:P1 ld:Q9 . # P1 istanza di e Q9 edizione
?item ldt:P11 ?autore .
?item ldt:P34 ?lingua .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?linguaLabel
Tutti gli URL ai full text collegati agli item di LibMovIt
# Tutti i full text collegati
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?URL WHERE {
?item ldt:P7 ?URL . #
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze della classe Citazioni, ordinate per autore, opera e pagina (Query di tipo esemplificativo)
# Istanze della classe Citazioni, ordinate per autore, opera e pagina
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ?opera .
?opera ldt:P11 ?autore .
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by ?autore xsd:integer(?pagina)
Tutte le citazioni tratte da La Lande
# Tutte le citazioni tratte da La Lande
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ld:Q1210 . #P8 tratto dall'opera Q201 opera di La Lande
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)
Tutte le citazioni tratte da La Marre
# Tutte le citazioni tratte da tutte le edizioni dell'opera di La Marre 1776
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ld:Q201 . #P8 tratto dall'opera Q201 opera di La Marre
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)
Tutte le citazioni tratte da Martyn
# Tutte le citazioni tratte da tutte le edizioni dell'opera di Martyn 1787
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ld:Q27 . #P8 tratto dall'opera Q27 opera di Martyn
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)
Tutte le citazioni tratte da Richard
# Tutte le citazioni tratte da tutte le edizioni dell'opera di Richard 1766
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ld:Q203 . #P8 tratto dall'opera Q203 opera di Richard
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)
Tutte le citazioni tratte da Albrizzi
# Tutte le citazioni tratte da tutte le edizioni dell'opera di Albrizzi 1740
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?brano ?bibliotecaLabel WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ld:Q72 . #P8 tratto dall'opera Q72 di Albrizzi
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)
Istanze delle citazioni relative alla Biblioteca dell'Istituto di Scienze di Bologna per data dell'opera e pagina
# Elenco delle citazioni per data dell'opera e pagina, relative alla Biblioteca dell'Istituto di Scienze di Bologna
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?brano ?data WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ?opera .
?opera ldt:P16 ?data .
?opera ldt:P11 ?autore .
?item ldt:P13 ld:Q371 . # P13 ha come soggetto la ?biblioteca
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by ?data
Istanze delle citazioni relative alla Biblioteca Marciana a Venezia, per data dell'opera e pagina
# Istanze delle citazioni relative alla Biblioteca Marciana a Venezia, per data dell'opera e pagina
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?brano ?data WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ?opera .
?opera ldt:P16 ?data .
?opera ldt:P11 ?autore .
?item ldt:P13 ld:Q78 . # P13 ha come soggetto la ?biblioteca
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by ?data
Persone
Istanze della classe Persona con l'eventuale ID Wikidata
# Tutte le persone con il loro eventuale ID Wikidata
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?ID_WD WHERE {
?item ldt:P1 ld:Q1 .
OPTIONAL { ?item ldt:P78 ?ID_WD } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Autori di viaggio
Istanze dei soli autori di viaggio con paese di cittadinanza e genere
#Tutti gli autori di viaggio paese di cittadinanza
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?persona ?personaLabel ?paese ?paeseLabel ?genere ?genereLabel WHERE {
?persona ldt:P51 ?paese . # P51 paese di cittadinanza
?persona ldt:P45 ?genere . # P45 genere
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?paeseLabel
Istanze degli autori di viaggio in ordine di numero decrescente di biblioteche citate nella propria opera
# Autori in base al numero delle biblioteche citate
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?autoreLabel (COUNT(?q) as ?count) WHERE {
?q ldt:P8 ?opera .
?opera ldt:P11 ?autore .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?autore ?autoreLabel
ORDER BY DESC(?count)
Cittadinanza degli autori di viaggio in ordine di numero decrescente
# Numero di autori censiti per paese di cittadinanza
# N.B.La proprietà P51 "Paese di cittadinanza" è stata inserita solo per gli autori delle opere
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?paeseLabel (COUNT(?persona) AS ?Numero) WHERE {
?persona ldt:P1 ld:Q1 . # Istanza di Persona
?persona ldt:P51 ?paese . # P51 paese di cittadinanza
# ?opera ldt:P11 ?persona . # la persona è autore di un'opera
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?paeseLabel
ORDER BY DESC(?Numero)
Occupazione degli autori di viaggio in ordine di numero decrescente
# Numero di autori censiti per occupazione
# N.B.La proprietà P70 "occupazione" è stata inserita solo per gli autori delle opere
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?occupazioneLabel (COUNT(?persona) AS ?Numero) WHERE {
?persona ldt:P1 ld:Q1 . # Istanza di Persona
?persona ldt:P70 ?occupazione . # P70 occupazione
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?occupazioneLabel
ORDER BY DESC(?Numero)
Genere degli autori di viaggio in ordine di numero decrescente
# Numero di persone censite per genere
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?genereLabel (COUNT(?persona) AS ?Numero) WHERE {
?persona ldt:P1 ld:Q1 . # Istanza di Persona
?persona ldt:P45 ?genere . # P45 genere
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?genereLabel
ORDER BY DESC(?Numero)
Altre persone
Istanze della classe Persona - esclusi gli autori di viaggio - con il loro eventuale ID Wikidata
# Tutte le persone - esclusi gli autori di viaggio - con il loro eventuale ID Wikidata
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?ID_WD WHERE {
?item ldt:P1 ld:Q1 .
OPTIONAL { ?item ldt:P78 ?ID_WD } .
FILTER NOT EXISTS { ?item ldt:P70 ?occupaz .}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze della classe Persone in ordine di numero decrescente di citazioni ricevute
# Numero di citazioni per ciascuna persona ;
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?soggetto ?soggettoLabel (COUNT(?item) AS ?totale) # mostra i soggetti citati e conta il totale di item, cioè citazioni
WHERE {
?item ldt:P1 ld:Q3. #definisce ?item come una citazione (Q3)
?item ldt:P13 ?soggetto . # definisce il soggetto come soggetto della citazione
?soggetto ldt:P1/ldt:P3* ld:Q1 . # il soggetto dev'essere una persona
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
GROUP BY ?soggetto ?soggettoLabel # raggruppa per soggetto
ORDER BY DESC(?totale) # ordina in numero decrescente
Ruoli in ordine di numero decrescente in base alle biblioteche collegate
# Ruoli in base al numero di biblioteche collegate
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX lp: <https://libmovit.wikibase.cloud/prop/>
PREFIX lpq: <https://libmovit.wikibase.cloud/prop/qualifier/>
PREFIX lps: <https://libmovit.wikibase.cloud/prop/statement/>
SELECT DISTINCT ?ruolo ?ruoloLabel (COUNT(?EC) AS ?Numero)
WHERE {
?biblioteca ldt:P1/ldt:P3* ld:Q5 . # Istanze di sottoclassi di biblioteca
?biblioteca ldt:P15 ?EC .
?biblioteca lp:P15 ?statement . # P15 entità collegata
?statement lps:P15 ?EC . # Valore dell'entità collegata
?statement lpq:P12 ?ruolo . # Ruolo dell'entità collegata
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
GROUP BY ?ruolo ?ruoloLabel
ORDER BY DESC(?Numero)
Occupazioni in ordine di numero decrescente associate in Wikidata alle persone censite in Wikibase LibMovIt diverse dagli autori di viaggio (QUERY FEDERATA)
# N. delle occupazioni più frequenti associate in Wikidata alle persone censite in Wikibase LibMovIt diverse dagli autori di viaggio
#title: Item persona con l'occupazione tratta da Wikidata
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?occupazione ?occlabel (COUNT(?item) AS ?Numero)
WHERE {
?item ldt:P1 ld:Q1.
?item ldt:P78 ?wdlink . # seleziona item di LibMovIt con link a Wikidata e definisce il valore del link
FILTER NOT EXISTS { ?item ldt:P70 ?occupazWL .}
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql>
{ ?wditem wdt:P106 ?occupazione . OPTIONAL { ?occupazione rdfs:label ?occlabel . FILTER(LANG(?occlabel) = "it") } . }
}
GROUP BY ?occupazione ?occlabel
ORDER BY DESC(?Numero)
Occupazione e paese di cittadinanza delle persone estratti da Wikidata (QUERY FEDERATA)
# Dati relativi all'occupazione e al paese di cittadinanza degli autori delle fonti di LibMovIt (occupazione e paese sono estratti da Wikidata)
#title:Occupazione e paese di cittadinanza degli autori delle fonti estratti da Wikidata
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?ID_WD ?occupazione ?paese WHERE {
?item ldt:P1 ld:Q1 .
?opera ldt:P11 ?item . #la persona è autore di un'opera
?citaz ldt:P8 ?opera . # l'opera è un'opera che ha almeno una citazione
?item ldt:P78 ?ID_WD .
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?ID_WD))) AS ?wditem)
OPTIONAL { SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P106 ?occupazione } .}
OPTIONAL { SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P27 ?paese } .}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by ?itemLabel
Biblioteche
Istanze della Classe Biblioteca
#Tutte le biblioteche di qualsiasi tipologia
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel WHERE {
?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza o P3* sottoclasse di Q5 biblioteca e delle sue sottoclassi
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Biblioteche in ordine di numero decrescente di citazioni ricevute
# Biblioteche in base al numero decrescente di citazioni;
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?soggetto ?soggettoLabel (COUNT(?item) AS ?totale) # mostra i soggetti citati e conta il totale di item, cioè citazioni
WHERE {
?item ldt:P1 ld:Q3. #definisce ?item come una citazione (Q3)
?item ldt:P13 ?soggetto . # definisce il soggetto come soggetto della citazione
?soggetto ldt:P1/ldt:P3* ld:Q5 . # il soggetto dev'essere una biblioteca o una sua sottoclasse
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
GROUP BY ?soggetto ?soggettoLabel # raggruppa per soggetto
ORDER BY DESC(?totale) # ordina in numero decrescente
Classi di biblioteche in ordine di numero decrescente di citazioni ricevute
# Tutte le classi di biblioteca con il numero delle relative istanze
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
SELECT ?istanzaLabel (COUNT(?q) AS ?count) WHERE {
?q ldt:P1 ?istanza .
?istanza ldt:P3* ld:Q5 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?istanzaLabel
ORDER BY DESC(?count)
Proprietari delle biblioteche in ordine di numero decrescente di istanze
#Proprietari delle biblioteche in base al numero di istanze
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
SELECT ?istanzaLabel (COUNT(?q) AS ?count) WHERE {
?q ldt:P1 ?istanza .
?istanza ldt:P3* ld:Q414 . # Q414 Biblioteca per proprietà
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?istanzaLabel
ORDER BY DESC(?count)
Contenuti delle biblioteche in ordine di numero decrescente di istanze
# Contenuti delle biblioteche in base al numero di istanze
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
SELECT ?istanzaLabel (COUNT(?q) AS ?count) WHERE {
?q ldt:P1 ?istanza .
?istanza ldt:P3* ld:Q415 . # Q415 Biblioteca per contenuto
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?istanzaLabel
ORDER BY DESC(?count)
Istanze delle biblioteche di tipo conventuale
# Tutte le istanze di biblioteca conventuale
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel WHERE {
?item ldt:P1 ld:Q74 . # P1 istanza di e Q74 biblioteca conventuale
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze delle biblioteche di tipo monastico
# Tutte le istanze di biblioteca monastica
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel WHERE {
?item ldt:P1 ld:Q406 . # P1 istanza di e Q74 biblioteca conventuale
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze di qualsiasi tipo di biblioteca e opere notevoli contenute
# Istanze di qualsiasi tipo di biblioteca e opere notevoli contenute
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?operaLabel WHERE {
?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza di o P3* sottoclasse di Q5 biblioteca
?item ldt:P18 ?opera . # P18 contiene
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Collezioni
Istanze della classe Collezioni
# Elenco di tutte le collezioni
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel WHERE {
?item ldt:P1/ldt:P3* ld:Q10 . # P1 istanza o P3* sottoclasse di Q10 collezione e delle sue sottoclassi
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze della classe Collezioni in ordine di numero decrescente di citazioni ricevute
# Numero di citazioni per ciascuna collezione ;
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?soggetto ?soggettoLabel (COUNT(?item) AS ?totale) #mostra i soggetti citati e conta il totale di item, cioè citazioni
WHERE {
?item ldt:P1 ld:Q3. #definisce ?item come una citazione (Q3)
?item ldt:P13 ?soggetto . # definisce il soggetto come soggetto della citazione
?soggetto ldt:P1/ldt:P3* ld:Q10 . # soggetto dev'essere una collezione
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
GROUP BY ?soggetto ?soggettoLabel # raggruppa per soggetto
ORDER BY DESC(?totale) # ordina in numero decrescente
Tipologie di oggetti contenuti nelle collezioni di ciascuna biblioteca, relativa quantità se disponibile e citazione d'autore
# Tipologie di oggetti contenuti nelle collezioni, relativa quantità se disponibile e citazione d'autore
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX lp: <https://libmovit.wikibase.cloud/prop/>
PREFIX lpq: <https://libmovit.wikibase.cloud/prop/qualifier/>
PREFIX lps: <https://libmovit.wikibase.cloud/prop/statement/>
PREFIX lpr: <https://libmovit.wikibase.cloud/prop/reference/>
SELECT DISTINCT ?biblioteca ?bibliotecaLabel ?tipo ?tipoLabel ?quantità ?citaz ?citazLabel
WHERE {
?biblioteca ldt:P1/ldt:P3* ld:Q5 . # Istanze di sottoclassi di biblioteca
# ?biblioteca ldt:P15 ?EC .
?biblioteca lp:P42 ?statement . # P42 "contiene oggetti del tipo"
?statement lps:P42 ?tipo . # Tipo di oggetti contenuti
OPTIONAL { ?statement lpq:P43 ?quantità }. # Quantità degli oggetti se disponibile
OPTIONAL { ?statement prov:wasDerivedFrom ?ref }. # ?statement prov:wasDerivedFrom ?ref .
OPTIONAL { ?ref lpr:P65 ?citaz }. #
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
ORDER BY ?bibliotecaLabel ?tipoLabel ?quantità
Tipologie di oggetti contenuti nelle collezioni, relativa consistenza se disponibile e citazione d'autore
# Tipologie di oggetti contenuti nelle collezioni, relativa consistenza se disponibile e citazione d'autore
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX lp: <https://libmovit.wikibase.cloud/prop/>
PREFIX lpq: <https://libmovit.wikibase.cloud/prop/qualifier/>
PREFIX lps: <https://libmovit.wikibase.cloud/prop/statement/>
PREFIX lpr: <https://libmovit.wikibase.cloud/prop/reference/>
SELECT DISTINCT ?biblioteca ?bibliotecaLabel ?tipo ?tipoLabel ?consistenza ?citaz ?citazLabel
WHERE {
?biblioteca ldt:P1/ldt:P3* ld:Q5 . # Istanze di sottoclassi di biblioteca
?biblioteca lp:P42 ?statement . # P42 "contiene oggetti del tipo"
?statement lps:P42 ?tipo . # Tipo di oggetti contenuti
OPTIONAL { ?statement lpq:P43 ?consistenza }. # Quantità degli oggetti se disponibile
OPTIONAL { ?statement prov:wasDerivedFrom ?ref }. # ?statement prov:wasDerivedFrom ?ref .
OPTIONAL { ?ref lpr:P65 ?citaz }. #
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
ORDER BY ?bibliotecaLabel ?tipoLabel ?consistenza
Tipologie di oggetti contenuti delle sole collezioni con dato di consistenza e citazione d'autore, in ordine di biblioteca, tipologia e data di pubblicazione
# Tipologie di oggetti contenuti delle sole collezioni con dato di consistenza e citazione d'autore, in ordine di biblioteca, tipologia e data di pubblicazione
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX lp: <https://libmovit.wikibase.cloud/prop/>
PREFIX lpq: <https://libmovit.wikibase.cloud/prop/qualifier/>
PREFIX lps: <https://libmovit.wikibase.cloud/prop/statement/>
PREFIX lpr: <https://libmovit.wikibase.cloud/prop/reference/>
SELECT DISTINCT ?biblioteca ?bibliotecaLabel ?tipo ?tipoLabel ?consistenza ?citaz ?citazLabel
WHERE {
?biblioteca ldt:P1/ldt:P3* ld:Q5 . # Istanze di sottoclassi di biblioteca
?biblioteca lp:P42 ?statement . # P42 "contiene oggetti del tipo"
?statement lps:P42 ?tipo . # Tipo di oggetti contenuti
# OPTIONAL { ?statement lpq:P43 ?consistenza }. # Quantità degli oggetti se disponibile
?statement lpq:P43 ?consistenza # Quantità degli oggetti obbligatoria
OPTIONAL { ?statement prov:wasDerivedFrom ?ref }. # ?statement prov:wasDerivedFrom ?ref .
OPTIONAL { ?ref lpr:P65 ?citaz }. #
OPTIONAL { ?citaz ldt:P8 ?opera } .
OPTIONAL { ?opera ldt:P16 ?dataPubbl } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
ORDER BY ?bibliotecaLabel ?tipoLabel ?dataPubbl
Numero di notabilia segnalati dai viaggiatori nelle biblioteche, in ordine decrescente
# Numero di notabilia segnalati dai viaggiatori nelle biblioteche
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?opera ?operaLabel (COUNT(?item) AS ?Numero)
WHERE {
?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza di o P3* sottoclasse di Q5 biblioteca
?item ldt:P18 ?opera . # P18 contiene
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?opera ?operaLabel
ORDER BY DESC(?Numero)
Numero di notabilia segnalati dai viaggiatori nelle biblioteche, in ordine crescente
# Numero di notabilia segnalati dai viaggiatori nelle biblioteche
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?opera ?operaLabel (COUNT(?item) AS ?Numero)
WHERE {
?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza di o P3* sottoclasse di Q5 biblioteca
?item ldt:P18 ?opera . # P18 contiene
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?opera ?operaLabel
ORDER BY DESC(?Numero)
Istanze dei notabilia (P18) segnalati nelle collezioni
# Elenco di tutti gli oggetti notevoli segnalati nelle collezioni
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel WHERE {
?contenitore ldt:P18 ?item
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze degli strumenti di corredo segnalati dai viaggiatori
# Elenco di tutti gli strumenti di corredo segnalati dai viaggiatori
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel
WHERE {
?item ldt:P1/ldt:P3* ld:Q54 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Servizi delle biblioteche (utenti, apertura, strumenti di corredo, orari)
Istanze delle biblioteche di cui è segnalata la tipologia di utenti
#Istanze delle biblioteche di cui è segnalata la tipologia di utenti
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?utenti ?utentiLabel WHERE {
?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza o P3* sottoclasse di Q5 biblioteca e delle sue sottoclassi
?item ldt:P21 ?utenti .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Tipologie di utenti associati alle biblioteche in ordine di numero decrescente
# Tipologie di utenti associati alle biblioteche in ordine di numero decrescente
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?utenti ?utentiLabel (COUNT(?item) AS ?Numero)
WHERE {
?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza o P3* sottoclasse di Q5 biblioteca e delle sue sottoclassi
?item ldt:P21 ?utenti .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?utenti ?utentiLabel
ORDER BY DESC(?Numero)
Accesso delle biblioteche in ordine di numero decrescente di istanze
# Numerosità delle classi di biblioteca per accesso
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
SELECT ?istanzaLabel (COUNT(?q) AS ?count) WHERE {
?q ldt:P1 ?istanza .
?istanza ldt:P3* ld:Q416 . # Q416 Biblioteca per accesso
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?istanzaLabel
ORDER BY DESC(?count)
Istanze delle biblioteche ad accesso pubblico
# Tutte le biblioteche ad accesso pubblico
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?luogoLabel WHERE {
?item ldt:P1 ld:Q75 . # P1 istanza di Q75 * biblioteca ad accesso pubblico
?item ldt:P20 ?luogo
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze delle biblioteche ad accesso limitato
# Tutte le biblioteche ad accesso limitato
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?luogoLabel WHERE {
?item ldt:P1 ld:Q296 . # P1 istanza di Q296 * biblioteca ad accesso limitato
?item ldt:P20 ?luogo
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Istanze degli strumenti di corredo segnalati dai viaggiatori
# Elenco di tutti gli strumenti di corredo segnalati dai viaggiatori
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel
WHERE {
?item ldt:P1/ldt:P3* ld:Q54 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Strumenti di corredo in ordine di numero decrescente di citazioni ricevute
# Numero di citazioni per ciascuno strumento di corredo ;
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?soggetto ?soggettoLabel (COUNT(?item) AS ?totale) # mostra i soggetti citati e conta il totale di item, cioè citazioni
WHERE {
?item ldt:P1 ld:Q3. #definisce ?item come una citazione (Q3)
?item ldt:P13 ?soggetto . # definisce il soggetto come soggetto della citazione
?soggetto ldt:P1/ldt:P3* ld:Q54 . # il soggetto dev'essere strumento di corredo o una sua sottoclasse
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
GROUP BY ?soggetto ?soggettoLabel # raggruppa per soggetto
ORDER BY DESC(?totale) # ordina in numero decrescente
Istanze di tutti i servizi biblioteconomici (consultazione, lettura, prestito ecc.) citati per le relative biblioteche
# Istanze di tutti i servizi citati per le relative biblioteche
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?servizio ?servizioLabel WHERE {
?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza di Q296 * biblioteca ad accesso limitato
?item ldt:P22 ?servizio .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Giorni e orari di apertura delle relative biblioteche
# Giorni e orari di apertura delle relative biblioteche
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?giorniApertura ?giorniAperturaLabel WHERE {
?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza di biblioteca
?item ldt:P24 ?giorniApertura .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Giorni e orari di chiusura delle relative biblioteche
# Giorni di chiusura delle relative biblioteche
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?giorniChiusura ?giorniChiusuraLabel WHERE {
?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza di biblioteca
?item ldt:P80 ?giorniChiusura .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Data visualization
Grafici
Grafico a bolle del numero di biblioteche in base al tipo
#Grafico che mostra la quantità delle biblioteche in base alla tipologia
#defaultView:BubbleChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?biblioteca ?bibliotecaLabel (COUNT(?biblioteca) as ?count) WHERE {
?item ldt:P1/ldt:P3* ld:Q5 .
?item ldt:P1 ?biblioteca .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,it,en". }
}
GROUP BY ?biblioteca ?bibliotecaLabel ?count
Grafico a bolle delle biblioteche citate più frequentemente (> 4 citazioni)
#Biblioteche citate più frequentemente grafico a bolle, con almeno 5 citazioni;
#defaultView:BubbleChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?biblioLabel (COUNT(?item) AS ?totale) #mostra le biblioteche e conta il totale di item, cioè citazioni
WHERE {
?item ldt:P1 ld:Q3. #definisce ?item come una citazione (Q3)
?item ldt:P13 ?biblio . # definisce la biblioteca come soggetto della citazione
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?biblioLabel # raggruppa per biblioteca
HAVING (?totale > 4)
ORDER BY DESC(?totale) # ordina in numero decrescente
Istogramma del numero di biblioteche in base al tipo
#title: Numero di biblioteche per tipologia
#defaultView:BarChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?biblioteca ?bibliotecaLabel (COUNT(?biblioteca) as ?count) WHERE {
?item ldt:P1/ldt:P3* ld:Q5 .
?item ldt:P1 ?biblioteca .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,it,en". }
}
GROUP BY ?biblioteca ?bibliotecaLabel ?count
Istogramma del numero di biblioteche citate più frequentemente (> 4 citazioni)
#Biblioteche citate più frequentemente grafico a barre, con almeno 5 citazioni;
#defaultView:BarChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?biblioLabel (COUNT(?item) AS ?totale) #mostra le biblioteche e conta il totale di item, cioè citazioni
WHERE {
?item ldt:P1 ld:Q3. #definisce ?item come una citazione (Q3)
?item ldt:P13 ?biblio . # definisce la biblioteca come soggetto della citazione
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?biblioLabel # raggruppa per biblioteca
HAVING (?totale > 4)
ORDER BY DESC(?totale) # ordina in numero decrescente
Istogramma del numero di autori di viaggio in base all'occupazione
#title: Numero di persone per occupazione
#defaultView:BarChart
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?occupazione ?occupazioneLabel (COUNT(?occupazione) as ?numero) WHERE {
?item ldt:P1 ld:Q1 .
?item ldt:P70 ?occupazione .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,it,en". }
}
GROUP BY ?occupazione ?occupazioneLabel ?numero
Grafi per esplorare l'ontologia di Wikidata LibMovIt
Grafo ad albero dell'ontologia di Wikibase LibMovIt (Q2)
#title:Grafo ad albero dell'ontologia di Wikibase LibMovIt
#defaultView:Graph
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P3* ld:Q2 .
OPTIONAL { ?linkTo ldt:P3 ?item . FILTER(?linkTo != ld:Q2) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero della sotto ontologia per la classe Biblioteca (Q5)
#title:Tutte le sottoclassi di biblioteca
#defaultView:Graph
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P3* ld:Q5 .
OPTIONAL { ?linkTo ldt:P3 ?item . FILTER(?linkTo != ld:Q5) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero della sotto ontologia per la classe Libro (Q58)
#title:Tutte le sottoclassi di Libro
#defaultView:Graph
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P3* ld:Q58 .
OPTIONAL { ?linkTo ldt:P3 ?item . FILTER(?linkTo != ld:Q58) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero della sotto ontologia per la classe Letteratura (Q4477)
#title:Tutte le sottoclassi di Letteratura
#defaultView:Graph
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P3* ld:Q4477 .
OPTIONAL { ?linkTo ldt:P3 ?item . FILTER(?linkTo != ld:Q4477) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero della sotto ontologia per la classe Organizzazione (Q11)
#title:Tutte le sottoclassi di organizzazione
#defaultView:Graph
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P3* ld:Q11 .
OPTIONAL { ?linkTo ldt:P3 ?item . FILTER(?linkTo != ld:Q58) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero della sotto ontologia per la classe Edificio (Q1995)
#title:Tutte le sottoclassi di edificio
#defaultView:Graph
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P3* ld:Q1995 .
OPTIONAL { ?linkTo ldt:P3 ?item . FILTER(?linkTo != ld:Q5) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Linee del tempo
Timeline degli scrittori di viaggio nati tra il 1600 e il 1700
# Timeline degli scrittori di viaggio nati tra il 1600 e il 1700
#title:Timeline degli scrittori di viaggio nati tra il 1600 e il 1700
#defaultView:Timeline
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?immagineLMI ?data WHERE {
?item ldt:P1 ld:Q1.
OPTIONAL { ?item ldt:P27 ?immagineLMI . }
?item ldt:P70 ld:Q334 .
?item ldt:P48 ?data .
?opera ldt:P11 ?item . # item che sono autori
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
FILTER (?data >= "1600-01-01T00:00:00Z"^^xsd:dateTime). # modificare data di inizio per un altro arco di tempo
FILTER (?data < "1700-01-01T00:00:00Z"^^xsd:dateTime).
}
ORDER BY ?data
Timeline degli scrittori di viaggio nati tra il 1700 e il 1800
# Timeline degli scrittori di viaggio nati tra il 1700 e il 1800
#title:Timeline degli scrittori di viaggio nati tra il 1700 e il 1800
#defaultView:Timeline
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?immagineLMI ?data WHERE {
?item ldt:P1 ld:Q1.
OPTIONAL { ?item ldt:P27 ?immagineLMI . }
?item ldt:P70 ld:Q334 .
?item ldt:P48 ?data .
?opera ldt:P11 ?item . # item che sono autori
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
FILTER (?data >= "1700-01-01T00:00:00Z"^^xsd:dateTime). # modificare data di inizio per un altro arco di tempo
FILTER (?data < "1800-01-01T00:00:00Z"^^xsd:dateTime).
}
ORDER BY ?data
Mappe
Mappa di tutte le città in cui ci sono biblioteche citate nelle opere dei viaggiatori
# Mappa di tutte le città in cui ci sono biblioteche citate nelle opere dei viaggiatori (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate
#defaultView:Map
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
?luogo ldt:P78 ?wdlink .
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Mappa di tutte le città in cui ci sono biblioteche citate nell'opera di Martyn
# Mappa di tutte le città in cui ci sono biblioteche citate da Martyn 1787 (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate da Martyn 1787
#defaultView:Map
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ld:Q27 . #P8 tratto dall'opera Q27 opera di Martyn
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
?luogo ldt:P78 ?wdlink .
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Mappa di tutte le città in cui ci sono biblioteche citate nell'opera di La Marre (volume 1)
# Mappa di tutte le città in cui ci sono biblioteche citate da La Marre (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate da La Marre nel primo volume
#defaultView:Map
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ld:Q201 . #P8 tratto dall'opera Q27 opera di La Marre
?item ldt:P82 "1" .
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
?luogo ldt:P78 ?wdlink .
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Mappa di tutte le città in cui ci sono biblioteche citate nell'opera di La Marre (volume 2)
# Mappa di tutte le città in cui ci sono biblioteche citate da La Marre (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate da La Marre nel secondo volume
#defaultView:Map
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord WHERE {
?item ldt:P4 ?brano . #P4 testo della citazione
?item ldt:P74 ?pagina .
?item ldt:P8 ld:Q201 . #P8 tratto dall'opera Q27 opera di La Marre
?item ldt:P82 "2" .
?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
?luogo ldt:P78 ?wdlink .
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Mappa delle città sede delle biblioteche citate
# Mappa di tutte le città in cui ci sono biblioteche citate nelle opere dei viaggiatori (le coordinate geografiche sono registrate solo su Wikidata)
#title:Citazioni in relazione alla città sede delle biblioteche menzionate
#defaultView:Map
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord ?layer WHERE {
?item ldt:P4 ?brano;
ldt:P13 ?biblioteca.
?biblioteca ldt:P20 ?luogo.
?luogo ldt:P78 ?wdlink.
?item ldt:P8 ?opera.
?opera ldt:P11 ?autore.
?autore rdfs:label ?autori.
FILTER((LANG(?autori)) = "en")
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
BIND(?autori AS ?layer)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE,en]". }
}
Mappa delle città sede delle biblioteche citate divise per decennio
# Mappa delle città con biblioteche citate nelle opere dei viaggiatori divise per decennio
#title:Mappa delle città con biblioteche citate nelle opere dei viaggiatori divise per decennio
#defaultView:Map
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?coord ?layer WHERE {
?item ldt:P4 ?brano;
ldt:P13 ?biblioteca.
?biblioteca ldt:P20 ?luogo.
?luogo ldt:P78 ?wdlink.
?item ldt:P8 ?opera.
?opera ldt:P11 ?autore.
?opera ldt:P16 ?data .
BIND(YEAR(?data) as ?anno)
BIND(IF( (?anno < 1711), "1700-1710", IF((1709 < ?anno && ?anno < 1721), "1710-1720", IF((1719 < ?anno && ?anno < 1731), "1720-1730", IF((1729 < ?anno && ?anno < 1741), "1730-1740", IF((1739 < ?anno && ?anno < 1751), "1740-1750", IF((1749 < ?anno && ?anno < 1761), "1750-1760", IF((1759 < ?anno && ?anno < 1771), "1760-1770", IF((1769 < ?anno && ?anno < 1781), "1770-1780", "Post-1780") ) ) ) )))) AS ?layer )
# ?autore rdfs:label ?autori.
# FILTER((LANG(?autori)) = "it")
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
# BIND(?autori AS ?layer)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE,en]". }
}
ORDER BY ?anno
Mappa del viaggio degli autori che contiene le citazioni delle biblioteche nelle città visitate divise per decennio
# Mappa del viaggio degli autori che contiene le citazioni delle biblioteche nelle città visitate divise per decennio
#title:Mappa del viaggio degli autori che contiene le citazioni delle biblioteche nelle città visitate divise per decennio
#defaultView:Map
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?coord ?layer WHERE {
?item ldt:P4 ?brano;
ldt:P13 ?biblioteca.
?biblioteca ldt:P20 ?luogo.
?luogo ldt:P78 ?wdlink.
?item ldt:P8 ?opera.
?opera ldt:P11 ?autore.
?opera ldt:P100 ?data .
BIND(YEAR(?data) as ?anno)
BIND(IF( (?anno < 1711), "1700-1710", IF((1709 < ?anno && ?anno < 1721), "1710-1720", IF((1719 < ?anno && ?anno < 1731), "1720-1730", IF((1729 < ?anno && ?anno < 1741), "1730-1740", IF((1739 < ?anno && ?anno < 1751), "1740-1750", IF((1749 < ?anno && ?anno < 1761), "1750-1760", IF((1759 < ?anno && ?anno < 1771), "1760-1770", IF((1769 < ?anno && ?anno < 1781), "1770-1780", "Post-1780") ) ) ) )))) AS ?layer )
# ?autore rdfs:label ?autori.
# FILTER((LANG(?autori)) = "it")
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
# BIND(?autori AS ?layer)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE,en]". }
}
ORDER BY ?anno
Query federate tra Wikibase LibMovIt e Wikidata
Occupazione e paese di cittadinanza delle persone estratti da Wikidata
# Dati relativi all'occupazione e al paese di cittadinanza degli autori delle fonti di LibMovIt (occupazione e paese sono estratti da Wikidata)
#title:Occupazione e paese di cittadinanza degli autori delle fonti estratti da Wikidata
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?ID_WD ?occupazione ?paese WHERE {
?item ldt:P1 ld:Q1 .
?opera ldt:P11 ?item . #la persona è autore di un'opera
?citaz ldt:P8 ?opera . # l'opera è un'opera che ha almeno una citazione
?item ldt:P78 ?ID_WD .
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?ID_WD))) AS ?wditem)
OPTIONAL { SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P106 ?occupazione } .}
OPTIONAL { SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P27 ?paese } .}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by ?itemLabel
Occupazioni delle persone inserite in LibMovIt tratte da Wikidata
# Tutti gli item persona con l'occupazione tratta da Wikidata
#title: Item persona con l'occupazione tratta da Wikidata
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?wditem ?occupazione ?occupazioneLabel # ?image
WHERE {
?item ldt:P1 ld:Q1.
?item ldt:P78 ?wdlink . # seleziona item di LibMovIt con link a Wikidata e definisce il valore del link
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P106 ?occupazione . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?itemLabel
Occupazioni, associate in Wikidata alle persone censite in Wikibase LibMovIt diverse dagli autori di viaggio, in ordine di numero decrescente
# N. delle occupazioni più frequenti associate in Wikidata alle persone censite in Wikibase LibMovIt diverse dagli autori di viaggio
#title: Item persona con l'occupazione tratta da Wikidata
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?occupazione (COUNT(?item) AS ?Numero)
WHERE {
?item ldt:P1 ld:Q1.
?item ldt:P78 ?wdlink . # seleziona item di LibMovIt con link a Wikidata e definisce il valore del link
FILTER NOT EXISTS { ?item ldt:P70 ?occupazWL .}
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P106 ?occupazione . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
GROUP BY ?occupazione
ORDER BY DESC(?Numero)
Query di lavoro
Persone che hanno immagini su Wikidata ma non in LibMovIt
# Tutti gli item persona che hanno un link a Wikidata e un'immagine su Wikidata ma non in LibMovIt
#title: Persone con immagini su Wikidata
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?wdlink ?wditem ?image WHERE {
?item ldt:P1 ld:Q1.
?item ldt:P78 ?wdlink . # seleziona item di LibMovIt con link a Wikidata e definisce il valore del link
FILTER NOT EXISTS { ?item ldt:P27 ?immagineLMI . }
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P18 ?image . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?itemLabel