Query

Query già predisposte

Statistiche sul questa istanza di WikiBase [1]

Categorie

Tipologie di biblioteca

# Tutte le sottoclassi di biblioteca

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P3* ld:Q5 .
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Tipologie di libro

# Tutte le sottoclassi di libri

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P3* ld:Q58 . # sottoclassi di Libro [Q58]
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

Ruoli

# Tutte le sottoclassi di ruolo di un'entità rispetto a un'altra entità

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P3* ld:Q83 . # sottoclassi [P3*] di ruolo [Q83]
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

ORDER BY ?itemLabel

Provalo!

Utenti

# Tutte le sottoclassi di utenti delle biblioteche

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P3* ld:Q123 . # sottoclassi [P3*] di ruolo [Q123]
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

ORDER BY ?itemLabel

Provalo!

Istanze

# Tutte le istanze di un tipo di biblioteca (Biblioteca conventuale)

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P1 ld:Q74 . # P1 istanza di e Q74 biblioteca conventuale
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

# Tutte le istanze di qualsiasi tipo di biblioteca 

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel WHERE {
  
  ?item ldt:P1/ldt:P3* ld:Q5 . # P1 istanza di o P3* sottoclasse di Q5 biblioteca
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Provalo!

# Tutte le istanze di edizioni in ordine di data di pubblicazione

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?autore ?autoreLabel ?data WHERE {
  
  ?item ldt:P1 ld:Q9 . # P1 istanza di e Q9 edizione
  ?item ldt:P11 ?autore .
  ?item ldt:P40 ?data
        
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?data

Provalo!

Citazioni

# Tutte le citazioni tratte da tutte le edizioni dell'opera di Martyn 1787

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q27 . #P8 tratto dall'opera Q27 opera di Martyn
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
        
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)

Provalo!

# Tutte le citazioni tratte da tutte le edizioni dell'opera di Albrizzi 1740

PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?bibliotecaLabel WHERE {
  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q72 . #P8 tratto dall'opera Q72 di Albrizzi
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Order by xsd:integer(?pagina)

Provalo!

Query federata

# Mappa di tutte le città in cui ci sono biblioteche citate da Martyn 1787 (le coordinate geografiche sono registrate solo su Wikidata)

#defaultView:Map
PREFIX ld: <https://libmovit.wikibase.cloud/entity/>
PREFIX ldt: <https://libmovit.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?brano ?bibliotecaLabel ?luogo ?luogoLabel ?wditem ?coord WHERE {  
  ?item ldt:P4 ?brano . #P4 testo della citazione
  ?item ldt:P74 ?pagina .
  ?item ldt:P8 ld:Q27 . #P8 tratto dall'opera Q27 opera di Martyn
  ?item ldt:P13 ?biblioteca . # P13 ha come soggetto la ?biblioteca
  ?biblioteca ldt:P20 ?luogo . # la ?biblioteca si trova P20 in un luogo
  ?luogo ldt:P2 ?wdlink .
  BIND(URI(REPLACE(STR(?wdlink), "https://www.wikidata.org/wiki/","http://www.wikidata.org/entity/")) AS ?wditem)
    SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P625 ?coord . }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Provalo!